BitmapData类的精确碰撞测试

import flash.display.BitmapData;
    import flash.display.BlendMode;
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    import flash.geom.ColorTransform;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.geom.Rectangle;

    public class HitTest {
        //========复杂（精确）碰撞测试
        public static function complexHitTestObject( target1:DisplayObject, target2:DisplayObject,  accurracy:Number = 1 ):Boolean {
            return complexIntersectionRectangle(target1,target2,accurracy).width != 0;
        }
        //========返回两目标对象重叠的区域矩形
        public static function intersectionRectangle( target1:DisplayObject, target2:DisplayObject ):Rectangle {

            //如果目标对象不存在，或者简单碰撞测试为否，那么就不可能重叠
            if ( !target1.root || !target2.root || !target1.hitTestObject( target2 ) ) {
                return new Rectangle  ;
            }

            //获取目标的边界信息Bounds
            var bounds1:Rectangle = target1.getBounds( target1.root );
            var bounds2:Rectangle = target2.getBounds( target2.root );

            // Determine test area boundaries.
            var intersection:Rectangle = new Rectangle();
            intersection.x   = Math.max( bounds1.x, bounds2.x );
            intersection.y    = Math.max( bounds1.y, bounds2.y );
            intersection.width      = Math.min( ( bounds1.x + bounds1.width ) - intersection.x, ( bounds2.x + bounds2.width ) - intersection.x );
            intersection.height = Math.min( ( bounds1.y + bounds1.height ) - intersection.y, ( bounds2.y + bounds2.height ) - intersection.y );

            return intersection;
        }
        //========返回复杂重叠的区域矩形
        public static function complexIntersectionRectangle( target1:DisplayObject, target2:DisplayObject, accurracy:Number = 1 ):Rectangle {
            if ( accurracy <= 0 ) {
                throw new Error("ArgumentError: Error #5001: Invalid value for accurracy",5001);
            }
            //如果简单碰撞为否，那么他们没有重叠
            if ( !target1.hitTestObject( target2 ) ) {
                return new Rectangle  ;
            }

            var hitRectangle:Rectangle = intersectionRectangle( target1, target2 );

            if ( hitRectangle.width * accurracy <1 || hitRectangle.height * accurracy <1 ) {
                return new Rectangle  ;
            }

            var bitmapData:BitmapData = new BitmapData( hitRectangle.width * accurracy, hitRectangle.height * accurracy, false, 0x000000 );

            //绘制第一个目标
            bitmapData.draw( target1, HitTest.getDrawMatrix( target1, hitRectangle, accurracy ), new ColorTransform( 1, 1, 1, 1, 255, -255, -255, 255 ) );
            //绘制第二个目标
            bitmapData.draw( target2, HitTest.getDrawMatrix( target2, hitRectangle, accurracy ), new ColorTransform( 1, 1, 1, 1, 255, 255, 255, 255 ), BlendMode.DIFFERENCE );

            //确定位图图像中完全包含指定颜色的所有像素的矩形区域,以找到重叠区域
            var intersection:Rectangle = bitmapData.getColorBoundsRect( 0xFFFFFFFF,0xFF00FFFF );

            bitmapData.dispose();//释放bitmapData对象的内存，返回width,height为-1

            if ( accurracy != 1 ) {
                intersection.x /= accurracy;
                intersection.y /= accurracy;
                intersection.width /= accurracy;
                intersection.height /= accurracy;
            }
            intersection.x += hitRectangle.x;
            intersection.y += hitRectangle.y;

            return intersection;
        }
        protected static function getDrawMatrix( target:DisplayObject, hitRectangle:Rectangle, accurracy:Number ):Matrix {//返回一个转换矩阵
            //accurracy精确度
            var localToGlobal:Point;

            var matrix:Matrix;

            var rootConcatenatedMatrix:Matrix = target.root.transform.concatenatedMatrix;

            localToGlobal = target.localToGlobal( new Point( ) );
            matrix = target.transform.concatenatedMatrix;
            matrix.tx = localToGlobal.x - hitRectangle.x;
            matrix.ty = localToGlobal.y - hitRectangle.y;

            matrix.a = matrix.a / rootConcatenatedMatrix.a;
            matrix.d = matrix.d / rootConcatenatedMatrix.d;
            if ( accurracy != 1 ) {
                matrix.scale( accurracy, accurracy );
            }

            return matrix;
        }

    }

}